Dateien mit ASP hochladen

Für Webhosting Windows-Pakete

Mit Hilfe von ASP können Sie Dateien über den Browser hochladen. Wie das geht, zeigen Ihnen folgende Beispielskripte:

ASP

MaxLength = x legt die maximale Dateigröße in Byte fest

<head>
        <title>Dateiupload per ASP</title>
</head>
<body bgcolor="white">
<%=Font%>
<%
' --- ASP FileUpload Modul GetFILE (C) 1999 by Stefan Falz

' --- Fehlerbehandlung aktivieren
' --- On Error Resume Next
' --- Zuweisen der Fehlerquelle, die bei einem Fehler ausgegeben werden soll
        Err.Source = "GetFILE HTTP-Upload"
' --- Konstante für Fehlerüberschrift
Const ErrHeader = "<b>Fehler</b><br><br>"

' --- Array deklarieren
Dim ErrArray(4)
        ErrArray(0) = "10900 - Ihre gesendete Datei ist zu groß."
        ErrArray(1) = "10901 - Unbekannter Fehler.<br>"
        ErrArray(2) = "10902 - Es wurde keine Datei gesendet oder die Übertragung ist fehlerhaft.<br>"
        ErrArray(3) = "10903 - Es wurde keine Textdatei gesendet.<br>"

' -- Aufrufen der Subroutine GetFILE
        Call GetFILE()


Private Sub GetFile()

' --- In dieser Subroutine wird der HTTP-Stream ausgelesen


' --- Deklarieren der Variablen
Dim FileText
    FileText = Request.BinaryRead(Request.TotalBytes)
Dim FileTextByte
    FileTextByte = ""
Dim FileTextNew
    FileTextNew = ""
Dim FilePosFirst
    FilePosFirst = 0
Dim FilePosLast
    FilePosLast = 0
Dim FileType
    FileType = ""
Dim strRevText
    strRevText = ""
Dim strFileName
    strFileName = ""
Dim strFileNameOnly
    strFileName = ""
Dim posFileName
    posFileName = 0
Dim rghFile
    rghFileName = ""
Dim lenFileTextByte
    lenFileTextByte = 0

' --- Angeben der max. Dateigröße + ca. 500 Byte für Dateiinformationen
Dim maxLength
    maxLength = 25500

' --- Abfrage der Größe des gesendeten Streams
        If Request.TotalBytes > maxLength Then
                Call Error_Handler(10900)
                Exit Sub
        End if

' --- Suchen nach HexCode 0D 0A 0D 0A (Dateianfang innerhalb des HTTP-Streams)
        FilePosFirst = InStrB(FileText, (ChrB(13) &amp; ChrB(10) &amp; ChrB(13) &amp; ChrB(10)))

' --- Suchen nach HexCode 0D 0A 2D 2D (Dateiende innerhalb des HTTP-Streams)
        FilePosLast = InStrB(FileText, (ChrB(13) &amp; ChrB(10) &amp; ChrB(45) &amp; ChrB(45)))

' --- Suchen nach HexCode 2D 0A 0D innerhalb des umgedrehten HTTP-Streams, da unter
' --- Umständen mehrere Dateiendekennzeichen vorhanden sind.
        strRevText = StrReverse(FileText)
        FilePosLast = InStrB(strRevText, (ChrB(45) &amp; ChrB(10)) &amp; ChrB(13))
        FilePosLast = LenB(FileText) - FilePosLast

' --- Abbruch bei Dateigröße 0 Byte
        If FilePosFirst = 0 Or FilePosLast = 0 Or FilePosLast - FilePosFirst < 5 Then
                Call Error_Handler(10902)
                Exit Sub
        End If
' --- Abbruch bei fehlender Angabe "Content-Disposition"
         If InStrB(FileText, ChrB(67) &amp; ChrB(111) &amp;  ChrB(110) &amp; ChrB(116) &amp; ChrB(101) &amp; ChrB(110)  &amp; ChrB(116) &amp; ChrB(45) &amp; ChrB(84) &amp;  ChrB(121) &amp; ChrB(112) &amp; ChrB(101) &amp; ChrB(58)  &amp; ChrB(32) &amp; ChrB(116) &amp; ChrB(101) &amp;  ChrB(120) &amp; ChrB(116) &amp; ChrB(47)) = 0 Then
                Call Error_Handler(10903)
                Exit Sub
        End if
' --- Abbruch, wenn ein Fehler aufgetreten ist, der nicht zu den obigen Fehlern gehört
        If Err.Number <> 0 Then
                Call Error_Handler(10901)
                Exit Sub
        End if
' --- Ermittlung des Dateinamens inkl. Pfad innerhalb des HTTP-Streams
         posFileName = InStrB(FileText, ChrB(102) &amp; ChrB(105)  &amp; ChrB(108) &amp; ChrB(101) &amp; ChrB(110) &amp;  ChrB(97) &amp; ChrB(109) &amp; ChrB(101) &amp; ChrB(61)  &amp; ChrB(34)) + 9

        rghFileText = RightB(FileText, LenB(FileText) - posFileName)

        strFileName = LeftB(rghFileText, InStrB(rghFileText, ChrB(34)) - 1)
                Response.Write "<strong>Dateiname inkl. Pfad: </strong>"
                        Response.BinaryWrite strFileName
                Response.Write "<br>"

' --- Ermittlung des Dateinamens exkl. Pfad innerhalb des HTTP-Streams
        posLastSlash = InStrB(StrReverse(strFileName), ChrB(92))

        strFileNameOnly = MidB(strFileName, LenB(strFileName) - posLastSlash, posLastSlash + 1)

                Response.Write "<strong>Dateiname exkl. Pfad: </strong>"
                        Response.BinaryWrite strFileNameOnly
                Response.Write "<br>"
' --- Abbruch, wenn ein Fehler aufgetrten ist
        If Err <> 0 Then
                Call Error_Handler(10901)
                Exit Sub
        End if

' --- Schreiben des Dateiinhalts in ByteArray
        FileTextByte = MidB(FileText, (FilePosFirst + 4), (FilePosLast - (FilePosFirst + 4)))

' --- Ermittlung der Dateigröße durch Auslesen der Länge des ermittelten Dateiinhalts
        lenFileTextByte = LenB(FileTextByte)

' --- Konvertierung des Dateiinhalts (Binärstream) in Ascii-Zeichen
        For i = 1 To lenFileTextByte
                FileTextNew = FileTextNew &amp; Chr(AscB(MidB(FileTextByte, i, 1)))
        Next

' --- Schreiben des ermittelten Dateiinhalts in eine Datei.
        Set objFileSys = Server.CreateObject("Scripting.FileSystemObject")
                 Set File =  objFileSys.CreateTextFile(Server.MapPath("./") &amp; "\" &amp;  Session.SessionID &amp; ".tmp", True, False)
                        File.WriteLine CStr(FileTextNew)
                        File.Close
                Set File = Nothing
        Set objFileSys = Nothing

' --- Ausgeben der Dateigröße in Bytes
         Response.Write "<strong>Dateigr&ouml;&szlig;e:  </strong>" &amp; lenFileTextByte &amp; "  Byte.<br><br>"

' --- Konvertieren des Dateiinhalts, da HTML-Seiten nicht korrekt angezeigt werden
        FileTextNew = Replace(FileTextNew, "<", "&lt;")
        FileTextNew = Replace(FileTextNew, ">", "&gt;")
        FileTextNew = Replace(FileTextNew, VbCrLf, "<br>" &amp; VbCrLf)
        FileTextNew = Replace(FileTextNew, Chr(9), "&nbsp;&nbsp;&nbsp;&nbsp;")

' --- Ausgabe des Dateiinhalts
        Response.Write FileTextNew
End Sub

Private Sub Error_Handler(intErrNumber)
' --- Ermitteln des übergebenen Fehlercodes und Ausgabe am Bildschirm
        Select Case intErrNumber
                Case 10900: Response.Write ErrHeader &amp; ErrArray(0)
                Case 10901: Response.Write ErrHeader &amp; ErrArray(1)
                Case 10902: Response.Write ErrHeader &amp; ErrArray(2)
                Case 10903: Response.Write ErrHeader &amp; ErrArray(3)
                Case Else: Response.Write ErrHeader &amp; Err.Description
        End Select
        Exit Sub
End Sub
%>
</body>
</html>

Als Benutzerschnittstelle dient hier bspw. ein einfaches HTML-Formular.

<html>
<head>
<title>Dateiupload per ASP</title>
</head>

<body>

<form method="POST" action="upload.asp" enctype="multipart/form-data" target="_new">
<input type="file" name="File" size="50"><br>
<input type="submit" value="DATEIUPLOAD STARTEN" name="Submit">
</form>
</body>
</html>

ASP.NET

Mit ASP.NET lässt sich das Upload-Skript wie folgt realisieren:


<%@ Page Language="VB" %>

<!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN" "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">

<script runat="server">

Sub UploadButton_Click(ByVal sender As Object, ByVal e As System.EventArgs)

' Specify the path on the server to
' save the uploaded file to.
Dim savePath As String = "e:\Kunden\Homepages\11\d12345678\www\UploadTest"

' Before attempting to perform operations
' on the file, verify that the FileUpload
' control contains a file.
If (FileUpload1.HasFile) Then
' Get the name of the file to upload.
Dim fileName As String = FileUpload1.FileName

' Append the name of the file to upload to the path.
savePath += fileName

' Call the SaveAs method to save the
' uploaded file to the specified path.
' This example does not perform all
' the necessary error checking.
' If a file with the same name
' already exists in the specified path,
' the uploaded file overwrites it.
FileUpload1.SaveAs(savePath)

' Notify the user of the name the file
' was saved under.
UploadStatusLabel.Text = "Your file was saved as " &amp; fileName

Else
' Notify the user that a file was not uploaded.
UploadStatusLabel.Text = "You did not specify a file to upload."
End If

End Sub

</script>

<html xmlns="http://www.w3.org/1999/xhtml" >
<head runat="server">
<title>FileUpload Example</title>
</head>
<body>
<form id="form1" runat="server">
<div>
<h4>File to upload:</h4>

<asp:FileUpload id="FileUpload1"
runat="server">
</asp:FileUpload>

<br /><br />

<asp:Button id="UploadButton"
Text="Upload file"
OnClick="UploadButton_Click"
runat="server">
</asp:Button>

<hr />

<asp:Label id="UploadStatusLabel"
runat="server">
</asp:Label>
</div>
</form>
</body>
</html>

Hinweis: In der folgenden Zeile müssen Sie noch den korrekten Pfad zu Ihrer Präsenz einzutragen:

Dim savePath As String = "e:\Kunden\Homepages\11\d12345678\www\UploadTest"