Excel: Die SUMMEWENN-Funktion erklärt

In Ihren Analysen und Berichten gehört das Zusammenzählen von Werten zum Normalfall. Excel macht Ihnen das Bilden von Summen leicht. Doch oft möchten Sie gar nicht einfach nur alle Werte zusammenzählen, sondern die Summe auf bestimmte Zahlen beschränken. Excel stellt Ihnen dafür die SUMMEWENN-Funktion zur Verfügung.

Wofür gibt es SUMMEWENN?

Mit SUMMEWENN verbindet Excel eine Funktion zur Summierung von Werten mit einer Wahrheitsabfrage. Nur wenn ein vom Nutzer spezifiziertes Kriterium zutrifft, kommt der Wert für das Zusammenzählen in Frage. Die festgelegten Kriterien können sich dabei entweder auf den Wert selbst beziehen oder aber auf eine Zelle, die mit dem Wert in Beziehung steht. So ist es beispielsweise möglich, nur Zahlen zu addieren, die kleiner sind als 1000 oder eben größer. Sie können aber auch nur solche Werte zusammenrechnen, die in die Kategorie „Bürobedarf“ gehören.

Mithilfe dieser Funktion konstruieren Sie Formeln, die auch auf Veränderungen in den Tabellen reagieren. Bearbeiten Sie beispielsweise die Beschreibungen von bestimmten Objekten, kommen diese nicht mehr für die Summierung in Betracht. Mithilfe von interaktiven Elementen können Sie so auch hilfreiche Formulare entwickeln.

Fakt

SUMMEWENN kombiniert die beiden Funktionen SUMME und WENN. Gleiche Effekte können Sie erreichen, indem Sie diese beiden Funktionen zu einer Formel zusammenfügen. Excel macht mit SUMMEWENN die Arbeit einfacher.

Syntax der SUMMEWENN-Funktion

Die Syntax von SUMMEWENN ist nicht sonderlich komplex:

=SUMMEWENN(Bereich;Suchkriterien;[Summe_Bereich])

Damit haben Sie drei Parameter, von denen der letzte nur optional ausgefüllt werden muss:

  • Bereich: Hier geben Sie die Zellen an, auf die das Kriterium angewendet werden soll. In den Zellen kommen Zahlen bzw. Werte vor. Auch Geldbeträge und Datumsangaben sind möglich. Die Zellen können aber auch Namen, Arrays oder Bezüge beinhalten. Hier können sich auch die Werte befinden, die Sie schließlich zusammenzählen möchten.
  • Suchkriterien: Die Suchkriterien lassen sich in unterschiedlichen Varianten festlegen. Zahlen, Ausdrücke, Bezüge, Texte oder auch weitere Funktionen können Sie hier unterbringen. Sollten Sie Text oder mathematische Formeln verwenden wollen, müssen Sie das Kriterium in doppelte Anführungszeichen setzen. Die Verwendung der beiden Platzhalter ? (für genau ein Zeichen) und * (für eine unbestimmte Zeichenfolge) ist möglich.
  • Summe_Bereich: Sollten die Werte, die Sie summieren wollen, nicht bereits im ersten Parameter enthalten sein, können Sie diese hier angeben.

Wenn man den optionalen Parameter Summe_Bereich einsetzt, sollten die Zellen in ihrer Anzahl und der Verteilung idealerweise den Angaben in Bereich folgen. Jede Zelle im ersten Parameter wird eine Zelle im dritten zugeordnet. Wenn Sie eine Diskrepanz herstellen, indem Sie beispielweise zehn Zellen unter Bereich festlegen, aber nur fünf unter Summe_Bereich, wird Excel den dritten Parameter mit fünf weiteren Zellen selbstständig auffüllen.

Fakt

SUMMEWENN funktioniert ähnlich wie die verwandte Funktion ZÄHLENWENN.

Neben SUMMEWENN gibt es auch die Weiterentwicklung SUMMEWENNS. Diese Funktion ist ab Excel 2007 verfügbar und gibt Nutzern die Möglichkeit, mehrere Kriterien anzugeben. Das Prinzip ist das gleiche wie bei SUMMEWENN: Sie definieren den Bereich, den Sie untersuchen lassen wollen, das Kriterium und den Bereich mit den zu addierenden Zellen. Der Unterschied liegt in erster Linie darin, dass Sie nun mehrere Kriterien angeben und damit auch mehr Bereiche auswählen können. Außerdem ist die Reihenfolge der Parameter etwas verändert:

=SUMMEWENNS(Summe_Bereich;Bereich1;Suchkriterien1;[Bereich2;Suchkriterien2];…)

Während der Parameter Summe_Bereich bei SUMMEWENN noch optional ist, sind bei der erweiterten Funktion die zu addierenden Zellen zwingend anzugeben. Sie müssen mindestens ein Kriterium und den entsprechenden Bereich nennen und dürfen sogar bis zu 127 Suchkriterien bestimmen.

SUMMEWENN an Beispielen erklärt

Die Excel-Funktion SUMMEWENN ist vielfältig einsetzbar. Die verschiedenen Möglichkeiten lassen sich am besten an Beispielen erklären. Diese können Sie als Ausgangspunkte für Ihre eigenen Projekte nehmen und entsprechend Ihrer Ziele anpassen.

Einfaches mathematisches Kriterium

Die simpelste Form der SUMMEWENN-Funktion hat man, wenn man einen mathematischen Vergleich einsetzt. Möglich sind hier die bekannten Vergleichszeichen in ihren Excel-konformen Varianten:

  • kleiner als: <
  • größer als: >
  • kleiner oder gleich: <=
  • größer oder gleich: >=
  • gleich: =
  • ungleich: <>
=SUMMEWENN(A2:A10;">=1000")

Die Formel addiert alle Werte in den Zellen A2 bis A10, die größer oder gleich 1000 sind.

Bezüge zu anderen Zellen

Interessanter wird SUMMEWENN noch, wenn weitere Zellbezüge hinzukommen. So kann man z. B. nur solche Werte zusammenzählen, die einem spezifischen Text in einer anderen Zelle entsprechen.

Nehmen wir an, Sie haben eine ungeordnete Liste mit mehreren Einzahlungen von verschiedenen Personen auf ein Sparkonto. Sie möchten nun sehen, wer bereits wie viel Geld überwiesen hat. Mit der SUMMEWENN-Funktion können Sie nur die Beträge zusammenzählen, die einem bestimmten Namen zugeordnet sind.

=SUMMEWENN(A2:A15;"Adam";B2:B15)

Auf diese Weise zählt die Funktion alle Geldbeträge zusammen, die von Adam überwiesen wurden. Analog können Sie die Formel für alle Namen anpassen und so schnell eine Liste erstellen.

Im Übrigen müssen Sie den Text gar nicht in die Formel selbst eintragen. Sie können auch einen Zellbezug herstellen, in dem die Namen zu finden sind. Besonders praktisch kann es z. B. auch sein, die Namen in einer Drop-down-Liste unterzubringen. Die Funktion liest das Suchkriterium dann aus der Zelle aus.

=SUMMEWENN(A2:A15;$D$2;B2:B15)

Datum und SUMMEWENN

Sehr hilfreich ist SUMMEWENN auch dadurch, dass die Funktion mit Datumsangaben umgehen kann. Nehmen wir an, es sollen nur solche Einzahlungen zusammengezählt werden, die bereits älter als ein Jahr sind. Auch hier gehen wir von einer unsortierten Liste aus. Sie müssen also das Datum der Einzahlung mit dem heutigen Datum vergleichen. Dabei helfen die beiden Funktionen EDATUM und HEUTE.

=SUMMEWENN(B2:B16;"<"&EDATUM(HEUTE();-12);C2:C16)

Die SUMMEWENN-Funktion überprüft, welche Zellen im Bereich von B2 bis B16 ein Datum enthalten, das geringer als das heutige Datum minus zwölf Monate ist. Nur die entsprechenden Zellen im Bereich von C2 bis C16, auf die dies zutrifft, werden zusammengerechnet.

Hinweis

Das Vergleichszeichen muss in doppelte Anführungszeichen gesetzt werden. Um den Vergleich an die folgende Formel zu knüpfen, verwenden Sie das kaufmännische Und-Zeichen (&).

Addieren bei wahren Ausdrücken

Sie möchten flexibel Werte zusammenrechnen? In der SUMMEWENN-Funktion lassen sich als Kriterien auch Wahrheitswerte eintragen. Sollte der Inhalt der Zelle WAHR sein, wird der Betrag in der entsprechenden Zelle mit in die Summe aufgenommen. Dies ist z. B. interessant, wenn Sie mit Kontrollkästchen arbeiten. Diese liefern entweder WAHR (bei gesetztem Häkchen) oder FALSCH (bei leerem Kästchen) in eine Zelle Ihrer Wahl. So kann man als Suchkriterium einfach auf diese Zellen verweisen und dort nach dem Ausdruck WAHR suchen lassen.

=SUMMEWENN(C2:C16;WAHR;B2:B16)

Die ausgelieferten Wahrheitswerte können Sie sichtbar lassen oder verstecken – entweder indem Sie die Zellen ausblenden oder einfach die Schrift weiß stellen. Nun können Sie ganz flexibel die Beträge auswählen, die Sie in die Summe aufnehmen möchten.

Mehr Kriterien mit SUMMEWENNS

Oftmals sollen nicht nur eines, sondern gleich mehrere Kriterien zutreffen, damit ein Wert in die Summe aufgenommen wird. Dies geht mit SUMMEWENN allein nicht, deshalb hat man die Funktion SUMMEWENNS eingeführt. Hiermit können Sie in Tabellen auch nach zwei oder mehr Kriterien suchen, die zutreffen müssen.

Nehmen wir an, Sie möchten die Gewinne eines Ihrer Verkäufer zusammenzählen, aber nur solche, die er in einer bestimmten Stadt gemacht hat.

=SUMMEWENNS(C2:C20;A2:A20;$F$2;B2:B20;$H$2)

In der Reihe C befinden sich die Werte, die Sie zusammenzählen möchten. In den beiden Reihen A und B suchen Sie nach den Kriterien, die Sie in F2 und H2 definieren. Nur wenn beide Kriterien zutreffen, wird der Betrag in die Summe aufgenommen.

Tipp

Dollarzeichen ($) vor Spalten- und Zeilenangaben einer Zelle sorgen dafür, dass Excel diese als absolut ansieht. Während Excel beim Kopieren der Formel normale Zellangaben relativ zur neuen Position anpasst, bleiben absolute Bezüge unverändert.